* SPSS syntax to generate:
* CFSR Item II) Disposition of C/AN for Duplicate Children.
* Syntax applies to NCANDS Child File V4.0. 
************************************************************************************.
****** Lines beginning with '*' are comments and are not executed by SPSS.     *****.
****** Name of State Master File must be entered in highlighted section below. *****.
************************************************************************************.
* Fields MAL1LEV MAL2LEV MAL3LEV MAL4LEV and MALDEATH are used to identify maltreatment victims.
* Field RPTDISP is used to identify the report disposition used in deriving CFSR disposition codes.

**********************************************************************************.
********** Enter name of the State Master File in following command line *********.
get file = 'ENTER STATE FILE NAME HERE'
   /keep = staterr subyr rptid chid mal1lev mal2lev mal3lev mal4lev maldeath rptdisp .

* Create flag variable FLVICTIM to identify maltreatment victims.
* If any of the maltreatment dispositions (MALLEV)are 1=sub or 2=ind, or 3=alt-resp victim
* the child was a victim.
* If the child died as result of the maltreatment MALDEATH=1, the child was a victim.
compute flvictim = 0 .
if (mal1lev le 3) flvictim = 1.
if (mal2lev le 3) flvictim = 1.
if (mal3lev le 3) flvictim = 1.
if (mal4lev le 3) flvictim = 1.
if (maldeath eq 1) flvictim = 1.

* Assign CFSR disposition to each r/c pair based upon victim status and report disposition.
* If the child was a victim, the CFSR disposition is 'Sub/Ind/AltVict'.
* If the child was not a victim but in a Sub/Ind/AltVict report,
*   the CFSR disposition is 'Unsubstantiated'.
* If the child was not a victim and not in a Sub/Ind/AltVict report, 
*   the CFSR disposition is based upon the report disposition.
* Report dispositions 1=sub, 2=ind & 3=altvictim are coded as 'Sub/Ind/AltVict' for CFSR (except non-victims), 
*    5=unsub and 6=unsub,intentionally false are coded as 'Unsubstantiated' for CFSR, 
*    All other dispositions are coded as 'Other' for CFSR.
if (flvictim eq 1) cfsrdisp = 1 .
if (flvictim eq 0 and (rptdisp le 3 or rptdisp eq 5 or rptdisp eq 6)) cfsrdisp = 2.
if (flvictim eq 0 and (rptdisp eq 4 or rptdisp gt 6)) cfsrdisp = 3.
var labels cfsrdisp 'CFSR Disposition' .
val labels cfsrdisp 1 'Sub/Ind/AltVict' 2 'Unsubstantiated' 3 'Other' .
* Format CFSRDISP (CFSR disposition code) to be an integer.
format cfsrdisp (f8.0).

* Active file currently holds records for duplicate children.
* No case selection is required.
* Counts displayed are counts of duplicate children by disposition within this disposition year. 
freq cfsrdisp.