* SPSS syntax to generate:
* CFSR Item II) Disposition of C/AN for Unique Children.
* Syntax applies to NCANDS Child File V4.0. 
************************************************************************************.
****** Lines beginning with '*' are comments and are not executed by SPSS.     *****.
****** Name of State Master File must be entered in highlighted section below. *****.
************************************************************************************.
* Field CHID is used to identify unique children.
* Fields MAL1LEV MAL2LEV MAL3LEV MAL4LEV and MALDEATH are used to identify maltreatment victims.
* Field RPTDISP is used to identify the report disposition used in deriving CFSR disposition codes.

**********************************************************************************.
********** Enter name of the State Master File in following command line *********.
get file = 'ENTER STATE FILE NAME HERE'
   /keep = staterr subyr rptid chid mal1lev mal2lev mal3lev mal4lev maldeath rptdisp .

* Create flag variable FLVICTIM to identify maltreatment victims.
* If any of the maltreatment dispositions (MALLEV)are 1=sub, 2=ind, or 3=alt-resp victim
* The child was a victim.
* If the child died as result of the maltreatment MALDEATH=1, the child was a victim.
compute flvictim = 0 .
if (mal1lev le 3) flvictim = 1.
if (mal2lev le 3) flvictim = 1.
if (mal3lev le 3) flvictim = 1.
if (mal4lev le 3) flvictim = 1.
if (maldeath eq 1) flvictim = 1.

* Assign CFSR disposition to each r/c pair based upon victim status and report disposition.
* If the child was a victim, the CFSR disposition is 'Sub/Ind/AltVict'.
* If the child was not a victim but in 'Sub/Ind/AltVict' report,
*   the CFSR disposition is 'Unsubstantiated'.
* If the child was not a victim and not in a 'Sub/Ind/AltVict' report, 
*   the CFSR disposition is based upon the report disposition.
* Report dispositions 1=sub, 2=ind, & 3=alt-resp/victim are coded as 'Sub/Ind/AltVict' 
* for CFSR, 5=unsub and 6=unsub,intentionally false are coded as 'Unsubstantiated' for CFSR. 
* All other dispositions are coded as 'Other' for CFSR.
if (flvictim eq 1) cfsrdisp = 1 .
if (flvictim eq 0 and (rptdisp le 3 or rptdisp eq 5 or rptdisp eq 6)) cfsrdisp = 2.
if (flvictim eq 0 and (rptdisp eq 4 or rptdisp gt 6)) cfsrdisp = 3.
var labels cfsrdisp 'CFSR Disposition' .
val labels cfsrdisp 1 'Sub/Ind/AltVict' 2 'Unsubstantiated' 3 'Other' .
* Format CFSRDISP (CFSR disposition code) to be an integer.
format cfsrdisp (f8.0).

* Group children with the same ID together using the SORT command.
* For children sharing the same ID, sort will list in order starting with lowest disposition code.
* The lowest disposition code is most severe (e.g., 1 = 'Sub/Ind/AltVict').
* Thus, a child a with a substantiated maltreatment in one report, and unsubstantiated 
*   in another, is categorized as substantiated by placing this record first and selecting it.
sort cases by chid cfsrdisp. 

* Remove multiple entries by selecting only the first (most severe) entry for each child.
* SPSS lag function below means: 
*  'Select record if the Child ID is not the same as previous Child ID (i.e., a new child)'.
* The selected record is always the first and also the one with most serious disposition code.
select if (chid ne lag(chid)) .

* Active file now holds records for unique children with most severe disposition code.
* Counts displayed are counts of unique children by disposition within this disposition year. 
crosstabs tables =  cfsrdisp by subyr /cells = count col.